打开系统的控制面板，在弹出的窗口中点击“卸载程序”命令，在新的操作窗口中点击左侧列表的“启用或关闭Windows功能”命令，在弹出的对话框中选择“SMB 1.0/CIFS文件共享支持”复选框进行安装。

1、计算机（右键）》管理》本地用户和组》Guest（右键-设置密码-确定）即空密码。
2、计算机（右键）》管理》本地用户和组》Guest（右键-取消帐户已禁用，点选“用户不能更改密码”和“密码永不过期”
3、控制面板》网络和共享中心》更改高级共享设置》打开“启用文件和打印机共享”，点选 “关闭密码保护共享 ”
4、调出“运行”（WIN7下：开始》运行；WIN8下 win+X）输入 gpedit.msc本地计算机策略》WINDOWS设置》安全设置》本地策略》安全选项》找到网络安全：LAN管理器身份验证级别（双击，设置为：仅发送NTLM响应)
5、同时设置：本地计算机策略》WINDOWS设置》安全设置》本地策略》用户权限分配》拒绝从网络访问这台计算机（双击打开，删除里面的所有用户。
6、计算机（右键）》管理》服务和应用程序》服务》TCP/IP NetBIOS Helper为启用状态。
7、完成。搞定以上所有设置。共享需要密码，网络无法访问等问题都可解决。

　　一般电脑小白根本不会设置，即使是技术人员，一项一项去设置也很麻烦。于是就在想，有没有程序可以一键进行设置，程序网上找的，做了一定的修改升级，经测试，可解决共享问题，不过由于情况复杂，不能保证 100% 完全解决问题。程序代码如下，保存为.bat文件，右击以管理员身份运行即可。

@echo off
color 2f
mode con cols=50 lines=30
title  局域网共享一键设置程序 — by Hack520.com
ver | findstr "5.">nul || set bulid=nt6 && goto sc_yhbl
set bulid=nt5
:sc_yhbl
reg query "HKCU\Environment" /v temp >nul 2>nul||set "usertemp=%USERPROFILE%\" && goto sc_top
set usertemp=%temp%\
:sc_top
cls
del /q %temp%\info.txt>nul 2>nul
:sc_menu
echo.&echo.&echo.
echo             局域网共享一键设置 2018.04.28
echo.
echo    --------------------------------------------
echo.&echo.&echo.
echo               1、查看网络信息
echo.
echo               2、简单共享（无密码）
echo.
echo               3、密码共享
echo.
echo               4、共享和权限设置
echo.
echo               5、软件更新与反馈
echo.&echo.&echo.&echo.&echo.
set select=
set str1=12345
set /p select= 输入数字，按回车:
if not defined select goto sc_wrong
echo %select%|findstr "[%str1%]">nul||goto sc_wrong
if %select%==1 (goto sc_info)
if %select%==2 (goto sc_zd)
if %select%==3 (goto sc_sd)
if %select%==4 (goto sc_gl) 
if %select%==5 (goto sc_update) 
:sc_wrong
mshta vbscript:msgbox("只能输入1-7的数字",64,"提示")(window.close) 
goto sc_top
:sc_info
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo                  正在处理信息....
if "%bulid%"=="nt6" goto sc_nt6
:sc_nt5
(echo.
echo.)>>%usertemp%info.txt
ping www.baidu.com -n 1 >nul || echo              互联网状态：       [ 离线 ]>>%usertemp%info.txt && goto sc_ver_nt5
echo              互联网状态：       [ 在线 ]>>%usertemp%info.txt
:sc_ver_nt5
(echo ----------------------------------------------------------
echo.)>>%usertemp%info.txt
for /f "skip=1 tokens=2-4 delims=, " %%a in ('wmic os get caption') do (
if exist %windir%\SysWOW64 echo         系统版本：       %%a %%b %%c  64位>>%usertemp%info.txt & goto sc_ver_nt5_next
echo         系统版本：       %%a %%b %%c  32位>>%usertemp%info.txt
)
:sc_ver_nt5_next
(echo.
echo         计算机名：            %COMPUTERNAME%
echo.)>>%usertemp%info.txt
for /f "tokens=2 delims= " %%a in ('net config workstation^|findstr /c:"工作站域"') do echo         工作组：              %%a>>%usertemp%info.txt & goto sc_info_nt5
:sc_info_nt5
(echo.
echo         当前用户：            %USERNAME%
echo.)>>%usertemp%info.txt
for /f "delims=" %%a in ('date /t') do echo         本机日期：            %%a>>%usertemp%info.txt
echo.>>%usertemp%info.txt
for /f "delims=" %%a in ('time /t') do echo         本机时间：            %%a>>%usertemp%info.txt
echo ---------------------------------------------------------->>%usertemp%info.txt
goto sc_info_more
:sc_nt6
(echo.
echo.)>>%usertemp%info.txt
ping www.baidu.com -n 1 >nul || echo          互联网状态：       [ 离线 ]>>%usertemp%info.txt && goto sc_ver_nt6
echo          互联网状态：       [ 在线 ]>>%usertemp%info.txt
:sc_ver_nt6
(echo --------------------------------------------------
echo.)>>%usertemp%info.txt
for /f "skip=1 tokens=2-5 delims=?, " %%a in ('wmic os get caption') do (
if exist %windir%\SysWOW64 echo    系统版本：      %%a %%b %%c %%d 64位>>%usertemp%info.txt & goto sc_ver_nt6_next
echo    系统版本：       %%a %%b %%c %%d 32位>>%usertemp%info.txt
)
:sc_ver_nt6_next
(echo.
echo    计算机名：            %COMPUTERNAME%
echo.)>>%usertemp%info.txt
for /f "tokens=2 delims= " %%a in ('net config workstation^|findstr /c:"工作站域"') do echo    工作组：              %%a>>%usertemp%info.txt
(echo.
echo    当前用户：            %USERNAME%
echo.)>>%usertemp%info.txt
for /f "delims=" %%a in ('date /t') do echo    本机日期：            %%a>>%usertemp%info.txt
echo.>>%usertemp%info.txt
for /f "delims=" %%a in ('time /t') do echo    本机时间：            %%a>>%usertemp%info.txt
echo -------------------------------------------------->>%usertemp%info.txt
:sc_info_more
if "%bulid%"=="nt5" ipconfig /all|findstr /v /c:"Windows IP Configuration"|findstr /v /c:"Host Name"|findstr /v /c:"Primary Dns Suffix"|findstr /v /c:"Node Type"|findstr /v /c:"IP Routing Enabled"|findstr /v /c:"WINS Proxy Enabled">>%usertemp%info.txt && goto sc_info_next
ipconfig /all|findstr /v /c:"Windows IP 配置"|findstr /v /c:"主机名"|findstr /v /c:"主 DNS 后缀"|findstr /v /c:"节点类型"|findstr /v /c:"IP 路由已启用"|findstr /v /c:"WINS 代理已启用">>%usertemp%info.txt
:sc_info_next
start /w notepad %temp%\info.txt
del /q %temp%\info.txt>nul 2>nul
goto sc_top
:sc_zd
call :sc_qxfix
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo                    开始修复......
net user guest /active:yes>nul 2>nul
net user guest "">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x1 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v LimitBlankPasswordUse /t REG_DWORD /d 0x0 /f>nul 2>nul
goto sc_main
:sc_sd
call :sc_qxfix
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo                    开始修复......
net user guest /active:no>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v NtlmMinClientSec /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v NtlmMinServerSec /t REG_DWORD /d 0x0 /f>nul 2>nul
goto sc_main
:sc_main
sc config LanmanWorkstation start= auto>nul 2>nul
sc config LanmanServer start= auto>nul 2>nul
sc config Winmgmt start= auto>nul 2>nul
sc config RpcSs start= auto>nul 2>nul
sc config Netman start= auto>nul 2>nul
sc config RasMan start= demand>nul 2>nul
sc config SSDPSRV start= auto>nul 2>nul
sc config BFE start= auto>nul 2>nul
sc config ALG start= demand>nul 2>nul
sc config SharedAccess start= auto>nul 2>nul
net start SharedAccess /y>nul 2>nul
sc config Browser start= auto>nul 2>nul
net start Browser /y>nul 2>nul
sc config Dnscache start= auto>nul 2>nul
net start Dnscache /y>nul 2>nul
sc config Dhcp start= auto>nul 2>nul
net start Dhcp /y>nul 2>nul
sc config lmhosts start= auto>nul 2>nul
net start lmhosts /y>nul 2>nul
sc config Spooler start= auto>nul 2>nul
net start Spooler /y>nul 2>nul
sc config upnphost start= demand>nul 2>nul
net start upnphost /y>nul 2>nul
reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\Netlogon" /v Start|findstr "0x4">nul 2>nul && sc config Netlogon start= demand>nul 2>nul
reg add "HKLM\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v TransportBindName /t REG_SZ /d \Device\ /f>nul 2>nul
reg delete "HKLM\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v SMB1 /F>nul 2>nul
reg delete "HKLM\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v SMB2 /F>nul 2>nul
reg delete "HKLM\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v SMBDeviceEnabled /F>nul 2>nul
sc config netbt start= system>nul 2>nul
net start netbt>nul 2>nul
if "%bulid%"=="nt6" goto sc_sernt6
:sc_sernt5
sc config PlugPlay start= auto>nul 2>nul
sc config TapiSrv start= auto>nul 2>nul
sc config Nla start= auto>nul 2>nul
net start Nla /y>nul 2>nul
netsh firewall set opmode mode=disable>nul 2>nul
goto sc_main2_etc
:sc_sernt6
sc config DcomLaunch start= auto>nul 2>nul
sc config RpcEptMapper start= auto>nul 2>nul
sc config SamSs start= auto>nul 2>nul
sc config nsi start= auto>nul 2>nul
sc config SstpSvc start= demand>nul 2>nul
sc config MpsSvc start= auto>nul 2>nul
net start MpsSvc /y>nul 2>nul
sc config NlaSvc start= auto>nul 2>nul
sc config netprofm start= auto>nul 2>nul
sc config fdPHost start= auto>nul 2>nul
sc config FDResPub start= auto>nul 2>nul
sc config HomeGroupListener start= auto>nul 2>nul
sc config WMPNetworkSvc start= auto>nul 2>nul
net start WMPNetworkSvc /y>nul 2>nul
sc config HomeGroupProvider start= auto>nul 2>nul
net start HomeGroupProvider /y>nul 2>nul
netsh advfirewall set allprofiles state off>nul 2>nul
:sc_main2_etc
(echo [Unicode]
echo Unicode=yes
echo [Version]
echo signature="$CHICAGO$"
echo Revision=1
echo [Privilege Rights]
echo sedenynetworklogonright = 
echo senetworklogonright = Everyone,Administrators,Users,Power Users,Backup Operators,guest)>>%usertemp%zcl.inf
secedit /configure /db %usertemp%zcl.sdb /cfg %usertemp%zcl.inf /log %usertemp%zcl.log /quiet
del /q %usertemp%zcl.*>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v LmCompatibilityLevel /t REG_DWORD /d 0x1 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v restrictanonymous /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v restrictanonymoussam /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v everyoneincludesanonymous /t REG_DWORD /d 0x1 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v NoLmHash /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v AutoShareServer /t REG_DWORD /d 0x1 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v AutoShareWks /t REG_DWORD /d 0x1 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v restrictnullsessaccess /t REG_DWORD /d 0x0 /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Browser\Parameters" /v MaintainServerList /t REG_SZ /d Auto /f>nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Browser\Parameters" /v IsDomainMaster /t REG_SZ /d FALSE /f>nul 2>nul
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters\Interfaces" /s /e /f "0x2"^|findstr "\Tcpip_"') do reg add "%%a" /v NetbiosOptions /t REG_DWORD /d 0x0 /f>nul 2>nul
reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v EnableLMHOSTS|findstr "0x0">nul 2>nul && reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v EnableLMHOSTS /t REG_DWORD /d 0x1 /f>nul 2>nul
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\RemoteComputer\NameSpace\{D6277990-4C6A-11CF-8D87-00AA0060F5BF}" /f>nul 2>nul
net use * /del /y>nul 2>nul
net config server /hidden:no>nul 2>nul
net share ipc$>nul 2>nul
goto sc_tip
:sc_gl
cls
reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest|findstr "0x1">nul 2>nul||goto classic
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x0 /f>nul 2>nul
set jlb=y
:classic
echo.&echo.&echo.&echo.
echo         功能：管理共享，修改共享文件夹权限
echo   ----------------------------------------------
echo.&echo.&echo.&echo.&echo.
echo                    【使用说明】
echo.&echo.
echo        点左侧“共享”可查看本机所有共享；
echo.
echo        右键点左侧“共享”可“新建共享”；
echo.
echo        右键点右侧共享可“停止共享”（能多选）；
echo.
echo        右键点右侧共享选“属性”可修改权限；
echo.&echo.&echo.&echo.&echo.&echo.&echo.
fsmgmt.msc
if "%jlb%"=="y" reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x1 /f>nul 2>nul
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo                     设置完成！
echo.&echo.&echo.
echo            按键盘任意键返回，或直接关闭！
pause>nul 2>nul
goto sc_top
:sc_tip
mshta vbscript:msgbox("修复完成，请重启计算机",64,"提示")(window.close) 
goto sc_exit
:sc_update
cls
start "%ProgramFiles%\Internet Explorer\iexplore.exe" "https://ihacksoft.com/303.html"
goto sc_top
goto :eof
:sc_qxfix
cls
echo.&echo.&echo.
echo                    【使用说明】
echo    --------------------------------------------
echo.
echo       鼠标复制共享文件夹地址栏路径粘贴到下方
echo.
echo         如果只共享打印机，就按下回车键跳过
echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo 粘贴路径，按回车:
echo.&echo.
set /p lj=
for %%a in ("%lj%") do set name=%%~na
net share "%name%"="%lj%">nul 2>nul
if "%bulid%"=="nt5" cacls "%lj%" /t /e /p everyone:f >nul 2>nul && goto :eof
icacls "%lj%" /grant everyone:(oi)(ci)f>nul 2>nul
goto :eof

设置共享文件

　　首先点击屏幕右下角通知栏中的网络图标，在弹出的网络连接中点击“网络和共享中心”，打开网络和共享中心。随后点击界面左侧的“更改高级共享设置”。在高级共享设置界面中，依次先勾选启用网络发现与启用文件及打印机共享，完毕后保存修改。

　　此时共享设置便完成了，现在我们在本地磁盘中找到需要共享的文件夹，在右键菜单中找到共享项，再选取合适的共享方式即可。

共享无法访问

　　当我们访问局域网共享文件，时常会出现共享文件夹无权限访问的问题，其实想要解决这一问题也不是难事，我们只需短短的几步就能实现。

　　首先同步工作组，不管局域网中电脑Windows操作系统的差异，必须要局域网中电脑工作组名称保持一致，如果出现工作组名称不统一，我们便可进入电脑的属性通过“计算机名称、域和工作组设置”项进行修改。

　　随后，我们右击共享文件夹，在弹出的菜单中选择属性，在弹出的新窗口中切换至共享后，点击“高级共享”按钮，勾选“共享此文件夹”后，单击“确定”保存设置并退出。

　　接下来，我们便可通过设置对来访者的权限进行设置。我们在共享文件夹属性界面中，切换至安全窗格，点击“编辑”按钮后，通过“添加”按钮，将Everyone添加至组或用户名中，点击确定即可保存退出便解决了这一问题。

提高访问共享文件的速度

　　我们在访问局域网中的共享文件时，时常会出现访问的速度与下载文件的速度特别慢，出现这样的问题，一般来说就是网卡配置出现了问题，当然，我们也不排除路由器的传输速度较慢，从而影响了局域网文件访问的速度。

　　修改网卡配置可以给系统访问共享文件提速不少，右键点击通知栏中的网络图片，在弹出的菜单中选取“网络和共享中心”，在弹出的新窗口中点击“本地连接”，打开网络状态窗口，随后点击界面左下方的“属性”，在弹出的新窗口中点击网卡配置按钮，接下来我们便可在开启的网卡属性窗口中切换至“高级”选项卡中，然后选中“大型传送分载v2(IPv4)”，将其设置为“关闭”，再点击确定按钮即可。

方法一：修改本机的工作组名称

　　工作组不一样的计算机在网络上有可能出现找不到其它计算机的现象。这时，可以单击桌面的“计算机”图标，选择“属性”菜单后，打开“系统”对话框。显示该计算机的工作组是MSHOME，而其他计算机的工作组则是WORKGROUP。于是，单击“更改设置”按钮，进入“系统属性”对话框。在“计算机名”选项卡下，单击“更改”按钮，把“工作组”名称改成“WORKGROUP”，单击“确定”，选择立即重新启动计算机。再次打开桌面的“网络”时，就可以看到其他的共享计算机。

方法二：开启“文件和打印机共享”

　　首先，右击桌面上的“网络”图标，选择“属性”菜单后，打开网络属性窗口。单击窗口左侧的“更改适配器设置”选项卡，打开“本地连接”对话框。右击“本地连接”图标后，选择“属性”菜单，打开“本地连接属性”窗口，没有发现“文件和打印机共享”列表。单击下方的“安装”按钮，打开“选择网络功能类型”窗口，选中“服务”项目，再单击“添加”按钮，系统会弹出“选择网络服务”窗口。选择“Fileand Printer Sharing for Microsoft Networks”列表，单击“确定”按钮即可。过一会，自动返回到网络设置窗口，在所列的网络服务中，显示出“Microsoft网络的文件和打印机共享”。然后，再启用“Microsoft网络客户端”服务。在“本地连接属性”窗口下，单击“安装”按钮，打开“选择网络功能类型”窗口，选中“客户端”项目，单击“添加”按钮，系统弹出“选择网络服务”窗口。选择“Client forMicroft NNetworks”3列表，单击“确定”按钮即可。不一会，便返回到网络设置窗口。在所列的网络服务中，即可显示“Microsoft网络客户端”。

方法三：开启网络发现

　　单击桌面的“开始”按钮，在搜索框中输入“services.msc”，回车后进人“服务”窗口。在窗口下找到“DNS Client'’列表后，双击打开“DNS Client的属生”对话框。把“启动类型”改成“自动”，单击确定即可。接着，再分别找到以下服务：FunctionDiscovery Resource Publication、SSDP Discovery、UPnP Device Host、Computer Browser、Server、TCP/IPNetBI0S Helper，并将它们的“启动类型”设置为自动苦动，就可开启网络发现功能。重新启动计算机后，进入“网络”窗口，就可以看到其他的共享计算机。
　　
方法四：开启Guest账户

　　依次单击桌面“开始一控制面板”菜单，打开“控制面板”窗口。把控制面板右上角的“查看方式”改为“大图标”，刷新以后，双击打开“用户账户”项目，单击“管理其他账户”，在打开新窗口中可看到Guest账户（来宾账户），并提示“来宾账户没有启用”。打开Guest账户图标后，在弹出的对话框中选择“启用”按钮即可。
　　
方法五：开启防火墙和重装网卡驱动

　　如果上述方法还是搞不定，还可依次单击桌面“开始→控制面板→Windows防火墙”菜单，打开“Windows防火墙”窗口。单击窗口左侧的“允许程序或功能通过Windows防火墙”，进入到“允许程序通过Windows防火墙通信”界面。在“允许的程序和功能”下，勾选“文件和打印机共享”后，单击“确定”即可。

　　接着，右击桌面的“计算机”图标，选择“设备管理器”菜单后，进入“设备管理器”窗口。单击“网络适配器”列表，展开所有的网络适配器。找到“本地连接”所对应的网卡右击后，选择“卸载”菜单，确认后进行网络适配器的卸载操作。重启计算机后，再次进入“设备管理器”窗口，右击“网络适配器”列表，选择“扫描检测硬件改动”菜单，开始扫描即插即用硬件，找到该硬件后自动安装驱动（如果系统找不到相应的驱动，可使用驱动精灵来安装）。