这是一款名为Windows文件保护专家的批处理软件，忘了以前是从哪里摘过来的。贴在这里主要不是把它拿过来用，而是学习和研究它的批处理代码。

@echo off
setlocal
color 0b
echo ===============================================================
echo.
echo Windows文件保护专家 v1.0
echo.
echo 说明：本程序可以有效的保护重要的文件不被删除或泄露。
echo 加入了删除文档的代码，可以删除那些被保护的文档
echo —技术仓库 www.hack0573.com
echo ===============================================================
:start
echo.
echo 建立文件保护文件夹 c:\FileLocker
if not exist c:\FileLocker..\nul md c:\FileLocker..\
echo 欢迎使用windwos保护专家 v1.0,请选择选项（1,2,3,4,5,q）;
echo 1.读取加密的文档
echo 2.存储保密文档
echo 3.建立秘密存储文档
echo 4.删除保密文档
echo 5.删除FileLocker
echo q.推出
echo.
set /p choice=
if {%choice%}=={} goto start
if /i %choice%==1 goto djm
if /i %choice%==2 goto cjm
if /i %choice%==3 goto jjm
if /i %choice%==4 goto sjm
if /i %choice%==5 goto df
if /i %choice%==q goto quit
goto start
rem========================加入秘密文件夹==========================
:jjm
echo.
echo 准备建立秘密文件夹...
echo 请输入密码:
set /p pass2c=
if {%pass2c%}=={} goto jjm
echo 开始根据密码建立保密文件夹......
md "c:\FileLocker..\%pass2c%..\"
echo 建立了保护文件夹!
echo.
goto start
rem ======================“加入”部分结束=========================
rem
rem =====================存储数据部分==============================
:cjm
echo.
echo 准备存储保密档案...
echo 请输入密码：
set /p pass=
if {%pass%}=={} goto cjm
if exist c:\FileLocker..\%pass%..\nul goto noerror
echo 发生错误，未发现建立加密保护文件夹！
goto start
:noerror
md "%userprofile%\桌面\Ready2Lock"
echo 请将你需要保护的文件复制到桌面上的Ready2Lock文件夹内(被保存的文件不能含有文件夹）
echo 注意：开始保护后会删除原文件!
echo 按任意键开始保护文件.......
pause > nul
echo 开始保护到C:\FileLocker文件夹内.........
copy "%userprofile%\桌面\Ready2Lock\*.*" "c:\FileLocker..\%pass%..\"
echo 保护完成，删除原文件........
del "%userprofile%\桌面\Ready2Lock\*.*" /Q
rd "%userprofile%\桌面\Ready2Lock"
echo 所有保护完成!
ping 127.0.0.1 -n 3 >nul
cls
goto start
rem ==========================存储部分结束=======================
rem
rem ===========================读取数据部分======================
:djm
echo.
echo 准备读取保密文件...
echo 请输入密码：
set /p pass2=
if {%pass2%}=={} goto djm
if not exist c:\FileLocker..\%pass2%..\nul echo 发生错误或不存在保护文档 & goto djm
echo 开始读取被保护的数据.......
if not exist "%userprofile%\桌面\Unlocked\nul" md "%userprofile%\桌面\Unlocked"
copy "c:\FileLocker..\%pass2%..\*.*" "%userprofile%\桌面\Unlocked"
echo 已经解密到桌面上的Unlocked文件夹内.........
ping 127.0.0.1 -n 3 >nul
goto start
rem ========================读取数据部分结束=======================
rem
rem ========================删除目录部分===========================
:sjm
echo.
echo.
echo 准备删除秘密文档.......
echo 请输入密码：
set /p pass2del=
if {%pass2del%}=={} goto sjm
echo 开始删除被保护文件夹
rmdir /s "c:\FileLocker..\%pass2del%..\" /Q
echo 已经删除被保护文件.......
goto start
rem ============================删除部分结束======================
rem
rem ===================Del FileLocker==============================
:df
echo.
echo 请删除之前确认FileLocker里面没有任何秘密文档.(y/n)
set /p yesorno=
if /i %yesorno%==y goto start2del
if /i %yesorno%==n goto sjm
goto df
:start2del
echo 开始删除FileLocker..........
rd "c:\FileLocker..\" >nul
if exist c:\FileLocker..\nul echo **删除失败，可能FileLocker里有别的秘密文档。**& goto fail
echo 成功删除!
:fail
ping 127.0.0.1 -n 3 >nul
goto start
rem ================Del Filelocker End====================
:quit
echo 感谢使用Windows文件保护专家 v1.0!
echo 按任意键退出本程序.
pause > nul
exit